第2回 Move言語でHelloWorldプログラムを作成する

Libraに関するセミナーのご依頼、その他ブロックチェーンに関するコンサルティングのお問い合わせはこちらからお願いいたします。（ページ右下の「サポート」をクリック）
連載全5回のインデックスはこちら。

言語仕様

• Move IR は、トランザクションスクリプトとモジュールで構成される（1ファイルに両方記載してもよいし、別々にしてimportしてもよい）。
• トランザクションスクリプトは main関数を記載する。
• 各関数の最後は return で終了する。

modules:
module M {
    foo() {
        return;
    }
}
 
script:
main() {
    return;
}

• Moveで扱えるプリミティブ型は、ブール値、64ビットの符号なし整数、256ビットのアカウントアドレス、固定長バイト配列がサポートされている。その他、構造体を使用することができる。

main() {
    let a: bool;
    let b: u64;
    let c: address;
    let d: bytearray;
・・・

• 変数は関数の先頭に宣言しなければならない。
• if や while、break、continue等の基本的な制御構文の書き方、演算子はRustと同じ。

付属のサンプルプログラム

libra/language/functional_tests/tests/testsuite/

• builtins/
  • ビルトイン関数として最初から用意されている関数の使い方のサンプル
• commands/
  • if や while 等の基本的な制御構文の使い方のサンプル
• comments/
  • コメント文の使い方のサンプル
• examples/
  • シンプルなMoveの構文のサンプル
• global_ref_count/
  • リソースの取得と格納方法のサンプル
• modules/
  • モジュールに関する様々な使い方のサンプル
• move_getting_started_examples/
  • ドキュメント「Getting Started With Move」に出てくるサンプルプログラム
• operators/
  • 加減乗除や比較の演算子の使い方のサンプル
• payments/
  • 送金プログラムのサンプル

HelloWorldプログラムの作成

modules:
module HelloWorld {
 
    resource ACC {
        total: u64,
    }
 
    // 初期化する関数
    public publish() {
        move_to_sender(ACC{ total: 0 });
        return;
    }
 
    // 足し算する関数
    public add(value: u64) {
        let acc: &mut R#Self.ACC;
        let total: u64;
        let my_address: address;
 
        // 自分（トランザクション実行者）のアドレスを取得
        my_address = get_txn_sender();
 
        // 自分が持つACCリソースを取得
        acc = borrow_global(move(my_address));
 
        // ACCリソースのtotal値を取得
        total = *(©(acc).total);
 
        // これまでのtotalに引数のvalueを加算してリソースに保存する
        *(&mut move(acc).total) = move(total) + move(value);
 
        return;
    }
 
    // 引き算する関数
    public sub(value: u64) {
        let acc: &mut R#Self.ACC;
        let total: u64;
        let my_address: address;
 
        my_address = get_txn_sender();
        acc = borrow_global(move(my_address));
        total = *(©(acc).total);
        *(&mut move(acc).total) = move(total) - move(value);
        return;
    }
 
    // クリアする関数
    public clear() {
        let acc: &mut R#Self.ACC;
        let total: u64;
        let my_address: address;
 
        my_address = get_txn_sender();
        acc = borrow_global(move(my_address));
        *(&mut move(acc).total) = 0;
        return;
    }
 
    // リソースの合計値を取得する関数
    public get_total(): u64 {
        let acc: &mut R#Self.ACC;
        let total: u64;
        let my_address: address;
 
        my_address = get_txn_sender();
        acc = borrow_global(move(my_address));
        total = *(&move(acc).total);
        return move(total);
    }
 
}
 
script:
import Transaction.HelloWorld;
main() {
    let total: u64;
 
    // 初期化して合計値が0であることを確認
    HelloWorld.publish();
    total = HelloWorld.get_total();
    assert(move(total) == 0, 99);
 
    // 10を加算して合計値が10であることを確認
    HelloWorld.add(10);
    total = HelloWorld.get_total();
    assert(move(total) == 10, 99);
 
    // 7を減算して合計値を3であることを確認
    HelloWorld.sub(7);
    total = HelloWorld.get_total();
    assert(move(total) == 3, 99);
 
    // 合計値をクリアして0であることを確認
    HelloWorld.clear();
    total = HelloWorld.get_total();
    assert(move(total) == 0, 99);
 
    return;
}

HelloWorldプログラムのテスト実行

libra/language/functional_tests/tests/testsuite/

$ cargo test -p functional_tests helloworld.mvir

test functional_tests::helloworld.mvir ... ok
test result: ok. 1 passed; 0 failed; 0 ignored; 0 measured; 245 filtered out

まとめ